m5stackで組込み!!

Arduinoによるm5stack開発のいろいろと...

スリープモード

今回は自動でスリープモードに入るような設定を作成しました。

deepSleepモード

名前の通り深いスリープです。スリープ復帰後にCPUは再起動されます。

    M5.Power.deepSleep(SLEEP_SEC(5));

lightSleepモード

名前の通り軽いスリープです。スリープ復帰後はスリープの次の行から実行されます。
deepSleepに比べ、省電力能力に欠けてしまいます。

    M5.Power.lightSleep(SLEEP_SEC(5));

サンプルコード

#include <M5Stack.h>

void setup() {
    // M5Stackの初期化
    M5.begin();
    // Powerの初期化
    M5.Power.begin();
}

void loop() {
    
    unsigned char aucCnt = 0;

    // テキストサイズ指定
    M5.Lcd.setTextSize(1);

    for( aucCnt = 0; aucCnt < 100; aucCnt++ )
    {
        M5.Lcd.printf("Cnt = %d\n", aucCnt );

        if( 3 == aucCnt )
        {
            M5.Power.lightSleep(SLEEP_SEC(5));
        }
        else if( 6 == aucCnt )
        {
            M5.Power.deepSleep(SLEEP_SEC(5));
        }

        delay(1000);
    }

    return;
}

いい感じですね!
youtu.be

ビープ音を出力

今回はビープ音を出力するプログラミングを作成しました。

音を鳴らすための初期化

ビープ音関係の初期化はM5.begin()では行っていないのでこちらの関数で初期化しましょう。
私は初期化を忘れてかなりの時間、ハマってました。。。

    M5.Speaker.begin();

音を鳴らすためのAPI

音を出すためのAPIはいくつかありますが、今回はM5.Speaker.tone()を使ってみたら、いきなり爆音!!!!
しかも、音量調節できないみたいです。。。
なので代わりにこちらを使います。

まずは使用するチャンネル設定の関数です。
第一引数に使用するチャンネル
第二引数にPWMの周波数
第三引数にデューティ比を表すビット数
この関数はM5.Speaker.begin()の中でコールされているので第一、第三引数はそのままで、第二引数の周波数だけ変えてあげればよいです。

    ledcSetup( TONE_PIN_CHANNEL, TONE_FREQ, 13);


次に音声音量調整の関数です。
第一引数に使用するチャンネル
第二引数にデューティ比
音量は第二引数のデューティ比を変更して調整します。

    ledcWrite( TONE_PIN_CHANNEL, 0x1FF>>(9-ucVol) );

サンプルコード

#include <M5Stack.h>

#define TONE_FREQ 900
#define TONE_STOP 0
#define TONE_PLAY 1

static unsigned char gucVol = 0;
static unsigned char gucToneSts = 0;

void setup() {
    // M5Stackの初期化
    M5.begin();
    // Speaker初期化
    M5.Speaker.begin();

    // BLACK Screen
    M5.Lcd.fillScreen(BLACK);
    // 横線
    M5.Lcd.drawFastHLine(0, 220, 320, WHITE);
    // 縦線
    M5.Lcd.drawFastVLine(106, 220, 20, WHITE);
    M5.Lcd.drawFastVLine(219, 220, 20, WHITE);
    // 矢印
    M5.Lcd.fillTriangle(  49, 232,  53, 224,  57, 232,WHITE );
//    M5.Lcd.fillTriangle( 159, 224, 167, 228, 159, 232,WHITE );
    M5.Lcd.fillTriangle( 269, 224, 273, 232, 277, 224,WHITE );

    // テキストサイズ指定
    M5.Lcd.setTextSize(1);
    // START
    M5.Lcd.setCursor(140, 224);
    M5.Lcd.print("START");
    // ボリューム値
    gucVol = 4;
    // トーン状態
    gucToneSts = TONE_STOP;
}

void loop() {
    M5.update();

    // Aボタン
    if (M5.BtnA.wasPressed()) {
        // 再生中
        if( TONE_PLAY == gucToneSts) {
            // 音量UP
            if( gucVol < 9 ){
                gucVol++;
            } else {
                gucVol = 9;
            }
            SetVolume( gucVol );
        }
    }
    // Bボタン
    if (M5.BtnB.wasPressed()) {
        // 開始
        if( TONE_STOP == gucToneSts) {
            ledcSetup( TONE_PIN_CHANNEL, TONE_FREQ, 13);
            SetVolume( gucVol );
            gucToneSts = TONE_PLAY;
            // テキストサイズ指定
            M5.Lcd.setTextSize(1);
            // START
            M5.Lcd.fillRect(107, 221, 87, 19, BLACK);
            M5.Lcd.setCursor(140, 224);
            M5.Lcd.print("STOP");
        }
        // 停止
        else {
            // ミュート
            M5.Speaker.mute();
            gucToneSts = TONE_STOP;
            // テキストサイズ指定
            M5.Lcd.setTextSize(1);
            // START
            M5.Lcd.fillRect(107, 221, 87, 19, BLACK);
            M5.Lcd.setCursor(140, 224);
            M5.Lcd.print("START");
        }
    }
    // Cボタン
    if (M5.BtnC.wasPressed()) {
        // 再生中
        if( TONE_PLAY == gucToneSts) {
            // 音量DOWN
            if( gucVol > 0 ){
                gucVol--;
            } else {
                gucVol = 0;
            }
            SetVolume( gucVol );
        }
    }

    //音量
    // テキストサイズ指定
    M5.Lcd.setTextSize(2);
    // ENTER
    M5.Lcd.setCursor(100, 100);
    M5.Lcd.printf("VOLUME: %d", gucVol);

    delay(100);

    return;
}

static void SetVolume( unsigned char ucVol )
{
    ledcWrite( TONE_PIN_CHANNEL, 0x1FF>>(9-ucVol) );
    
    return;
}

これで爆音でなるビープ音から解放された。
www.youtube.com

m5stackで組込み!

今まで個々の機能を作ってきましたが、それぞれの機能を合わせて色々とできないかなーと思っていたところ、
やはり同じように考えている方がいました。

raspida.com

私もこんな感じでこれからは作っていきたいと思います。